« ESP-WROOM-02で読み取ったセンサ値をスマホに表示する | トップページ | Magic keyboardとMagic trackpad 2を購入 »

ESP-WROOM-02でMQTTを使う

IoT関連のプロトコルであるMQTTに興味があったのですが、ESP-WROOM-02 Arduino開発環境で試してみました。

準備

ESP-WROOM-02からMQTT broker(test.mosquitto.org)にmessageをpublishし、Raspberry Piでmessageをsubscribeします。Raspberry Piでmessageをsubscribeするためのパッケージを以下の通りインストールします。(subscribeするだけなら、mosquitto-clientsのみで良いかもしれません)。

$ sudo apt-get install mosquitto
$ sudo apt-get install mosquitto-clients

Arduino環境用のライブラリーArduino Client for MQTTをダウンロードしてlibraryフォルダーにコピーします。


サンプルコード

Arduino Client for MQTT (pubsubclient) のサンプルコードにmqtt_esp8266があり、このコードを若干修正して使っています。

/*
 Basic ESP8266 MQTT example

 This sketch demonstrates the capabilities of the pubsub library in combination
 with the ESP8266 board/library.

 It connects to an MQTT server then:
  - publishes "hello world" to the topic "outTopic" every two seconds
  - subscribes to the topic "inTopic", printing out any messages
    it receives. NB - it assumes the received payloads are strings not binary
  - If the first character of the topic "inTopic" is an 1, switch ON the ESP Led,
    else switch it off

 It will reconnect to the server if the connection is lost using a blocking
 reconnect function. See the 'mqtt_reconnect_nonblocking' example for how to
 achieve the same result without blocking the main loop.

 To install the ESP8266 board, (using Arduino 1.6.4+):
  - Add the following 3rd party board manager under "File -> Preferences -> Additional Boards Manager URLs":
       http://arduino.esp8266.com/stable/package_esp8266com_index.json
  - Open the "Tools -> Board -> Board Manager" and click install for the ESP8266"
  - Select your ESP8266 in "Tools -> Board"

*/

#include <ESP8266WiFi.h>
#include <PubSubClient.h>

#define LED 12

// Update these with values suitable for your network.

const char* ssid = "ssid";
const char* password = "password";
const char* mqtt_server = "test.mosquitto.org";

WiFiClient espClient;
PubSubClient client(espClient);

char mTopic[]="test-topc-ESP-WROOM-02/sensor";
long lastMsg = 0;
char msg[50];
int value = 0;

void setup() {
  pinMode(LED, OUTPUT);     // Initialize the BUILTIN_LED pin as an output
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void setup_wifi() {

  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();

  // Switch on the LED if an 1 was received as first character
  if ((char)payload[0] == '1') {
    digitalWrite(LED, HIGH);   // Turn the LED on (Note that LOW is the voltage level
    // but actually the LED is on; this is because
    // it is acive low on the ESP-01)
  } else {
    digitalWrite(LED, LOW);  // Turn the LED off by making the voltage HIGH
  }

}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect("ESP8266Client")) {
      Serial.println("connected");
      // Once connected, publish an announcement...
      client.publish("outTopic", "hello world");
      // ... and resubscribe
      client.subscribe("inTopic");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;
    ++value;
    snprintf (msg, 75, "ESP-WROOM-02 #%ld", value);
    Serial.print("Publish message: ");
    Serial.println(msg);
    client.publish(mTopic, msg);
  }
}

MessageのSubscribe

RaspberryPiに以下のコマンドを入力することでMessageをSubscribeします。

$ mosquitto_sub -d -h test.mosquitto.org -t test-topc-ESP-WROOM-02/sensor

Received CONNACK
Received SUBACK
Subscribed (mid: 1): 0
Received PUBLISH (d0, q0, r0, m0, 'test-topc-ESP-WROOM-02/sensor', ... (15 bytes))
ESP-WROOM-02 #1
Received PUBLISH (d0, q0, r0, m0, 'test-topc-ESP-WROOM-02/sensor', ... (15 bytes))
ESP-WROOM-02 #2
Received PUBLISH (d0, q0, r0, m0, 'test-topc-ESP-WROOM-02/sensor', ... (15 bytes))
ESP-WROOM-02 #3
Received PUBLISH (d0, q0, r0, m0, 'test-topc-ESP-WROOM-02/sensor', ... (15 bytes))
ESP-WROOM-02 #4
Received PUBLISH (d0, q0, r0, m0, 'test-topc-ESP-WROOM-02/sensor', ... (15 bytes))
ESP-WROOM-02 #5
Received PUBLISH (d0, q0, r0, m0, 'test-topc-ESP-WROOM-02/sensor', ... (15 bytes))
ESP-WROOM-02 #6
Received PUBLISH (d0, q0, r0, m0, 'test-topc-ESP-WROOM-02/sensor', ... (15 bytes))
ESP-WROOM-02 #7
Received PUBLISH (d0, q0, r0, m0, 'test-topc-ESP-WROOM-02/sensor', ... (15 bytes))
ESP-WROOM-02 #8

参考資料

« ESP-WROOM-02で読み取ったセンサ値をスマホに表示する | トップページ | Magic keyboardとMagic trackpad 2を購入 »

ESP-WROOM-02」カテゴリの記事

コメント

この記事へのコメントは終了しました。

2023年6月
        1 2 3
4 5 6 7 8 9 10
11 12 13 14 15 16 17
18 19 20 21 22 23 24
25 26 27 28 29 30  
無料ブログはココログ